11

Building on example 10. ...in addition reactions are endowed with a direction, flux bounds and possibly the description of the enzymes that catalyze it.

Use at

• https://rdf.metanetx.org/sparql/

PREFIX mnx: <https://rdf.metanetx.org/schema/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

# Building on example 10. ...in addition reactions are endowed with a direction, flux
# bounds and possibly the description of the enzymes that
# catalyze it.

SELECT ?reac_orig_label ?reac_mnx_label ?lb ?ub ?dir ?cata_orig (GROUP_CONCAT(?cplx_label ; separator=' OR ') AS ?cplx_info )
FROM <https://rdf.metanetx.org/> WHERE{
    ?mnet rdfs:label 'bigg_e_coli_core';
          mnx:gpr ?gpr .
    ?gpr rdfs:label ?reac_orig_label ;
         rdfs:comment ?cata_orig ;
         mnx:reac ?reac ;
         mnx:cata ?cata .
    ?reac rdfs:label ?reac_mnx_label .
    ?cata mnx:lb ?lb ;
          mnx:ub ?ub ;
          mnx:dir ?dir ;
          mnx:cplx ?cplx .
    ?cplx rdfs:label ?cplx_label .
}
GROUP BY ?reac ?reac_orig_label ?reac_mnx_label ?lb ?ub ?dir ?cata_orig ORDER BY (?reac)

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v6("?cata")
  v5("?cata_orig"):::projected 
  v11("?cplx")
  v13("?cplx_info")
  v12("?cplx_label"):::projected 
  v10("?dir"):::projected 
  v3("?gpr")
  v8("?lb"):::projected 
  v2("?mnet")
  v1("?reac")
  v7("?reac_mnx_label"):::projected 
  v4("?reac_orig_label"):::projected 
  v9("?ub"):::projected 
  c2(["bigg_e_coli_core"]):::literal 
  v2 --"rdfs:label"-->  c2
  v2 --"mnx:gpr"-->  v3
  v3 --"rdfs:label"-->  v4
  v3 --"rdfs:comment"-->  v5
  v3 --"mnx:reac"-->  v1
  v3 --"mnx:cata"-->  v6
  v1 --"rdfs:label"-->  v7
  v6 --"mnx:lb"-->  v8
  v6 --"mnx:ub"-->  v9
  v6 --"mnx:dir"-->  v10
  v6 --"mnx:cplx"-->  v11
  v11 --"rdfs:label"-->  v12
  bind1[/"?cplx_label"/]
  v12 --o bind1
  bind1 --as--o v13