108_uniprot_signature_match_start_end

rq turtle/ttl

• InterPro
• search within sequence
• domain

List all InterPro member database signature match start and end for a specific UniProtKB protein.

Use at

• https://sparql.uniprot.org/sparql/

PREFIX faldo: <http://biohackathon.org/resource/faldo#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX up: <http://purl.uniprot.org/core/>

SELECT 
  ?protein ?interproMemberDatabaseXref ?matchStart ?matchEnd
WHERE{
  GRAPH <http://sparql.uniprot.org/uniprot> {
    VALUES ?protein {<http://purl.uniprot.org/uniprot/P05067>} .
    ?protein rdfs:seeAlso ?sa .
  }
  GRAPH <http://sparql.uniprot.org/uniparc> {
    ?uniparc up:sequenceFor ?protein ;
      rdfs:seeAlso ?interproMemberDatabaseXref .
    ?interproMemberDatabaseXref up:signatureSequenceMatch ?sam .
    ?sam faldo:begin ?sab ;
      faldo:end ?sae .
    ?sab faldo:position ?matchStart ;
      faldo:reference ?uniparc .
    ?sae  faldo:position ?matchEnd ;
      faldo:reference ?uniparc .
  }
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v4("?interproMemberDatabaseXref"):::projected 
  v9("?matchEnd"):::projected 
  v8("?matchStart"):::projected 
  v1("?protein"):::projected 
  v2("?sa")
  v6("?sab")
  v7("?sae")
  v5("?sam")
  v3("?uniparc")
  bind0[/VALUES ?protein/]
  bind0-->v1
  bind00([http://purl.uniprot.org/uniprot/P05067])
  bind00 --> bind0
  v1 --"rdfs:seeAlso"-->  v2
  v3 --"up:sequenceFor"-->  v1
  v3 --"rdfs:seeAlso"-->  v4
  v4 --"up:signatureSequenceMatch"-->  v5
  v5 --"faldo:begin"-->  v6
  v5 --"faldo:end"-->  v7
  v6 --"faldo:position"-->  v8
  v6 --"faldo:reference"-->  v3
  v7 --"faldo:position"-->  v9
  v7 --"faldo:reference"-->  v3