133_mapping_panther_rhea_uniprot_eco

enzyme
PANTHER
Rhea

Generate a mapping table for PANTHER family - Rhea - UniProt Protein - ECO code

Use at

https://sparql.uniprot.org/sparql

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX up:  <http://purl.uniprot.org/core/>
PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>

SELECT
?pantherFamily
?rhea
?protein
?eco
WHERE {
  # Protein has a catalytic activity annotation with a Rhea reaction
  ?protein up:annotation ?ann .
  ?ann up:catalyticActivity ?ca .
  ?ca up:catalyzedReaction ?rhea .

  # The catalyticActivity statement has experimental evidence and a citation
  ?reif rdf:subject   ?ann ;
        rdf:predicate up:catalyticActivity ;
        rdf:object    ?ca ;
        up:attribution ?attr .
  ?attr up:evidence ?eco .

  # Protein is linked to a PANTHER family cross-reference
  ?protein rdfs:seeAlso ?pantherFamily .
  ?pantherFamily up:database <http://purl.uniprot.org/database/PANTHER> .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v2("?ann")
  v6("?attr")
  v3("?ca")
  v7("?eco"):::projected 
  v8("?pantherFamily"):::projected 
  v1("?protein"):::projected 
  v5("?reif")
  v4("?rhea"):::projected 
  c11([http://purl.uniprot.org/database/PANTHER]):::iri 
  c2(["up:catalyticActivity"]):::iri 
  v1 --"up:annotation"-->  v2
  v2 -->c2--> v3
  v3 --"up:catalyzedReaction"-->  v4
  v5 --"rdf:subject"-->  v2
  v5 --"rdf:predicate"-->  c2
  v5 --"rdf:object"-->  v3
  v5 --"up:attribution"-->  v6
  v6 --"up:evidence"-->  v7
  v1 --"rdfs:seeAlso"-->  v8
  v8 --"up:database"-->  c11