SIB SPARQL examples

← All examples

151_membrane_orientation_of_subcellular_location

rq turtle/ttl

Find reviewed human proteins with a known membrane orientation (e.g. cytoplasmic side vs. lumenal side) for one of their subcellular locations

Use at

PREFIX up: <http://purl.uniprot.org/core/>
PREFIX taxon: <http://purl.uniprot.org/taxonomy/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT
  ?protein
  ?subcellularLocation
  ?orientation
WHERE {
  ?protein a up:Protein ;
    up:organism taxon:9606 ;
    up:reviewed true ;
    up:annotation ?annotation .
  ?annotation a up:Subcellular_Location_Annotation ;
    up:locatedIn ?location .
  ?location up:cellularComponent ?component ;
    up:orientation ?orientationResource .
  ?component skos:prefLabel ?subcellularLocation .
  ?orientationResource skos:prefLabel ?orientation .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v2("?annotation")
  v4("?component")
  v3("?location")
  v7("?orientation"):::projected 
  v5("?orientationResource")
  v1("?protein"):::projected 
  v6("?subcellularLocation"):::projected 
  c6(["true^^xsd:boolean"]):::literal 
  c8(["up:Subcellular_Location_Annotation"]):::iri 
  c2(["up:Protein"]):::iri 
  c4(["taxon:9606"]):::iri 
  v1 --"a"-->  c2
  v1 --"up:organism"-->  c4
  v1 --"up:reviewed"-->  c6
  v1 --"up:annotation"-->  v2
  v2 --"a"-->  c8
  v2 --"up:locatedIn"-->  v3
  v3 --"up:cellularComponent"-->  v4
  v3 --"up:orientation"-->  v5
  v4 --"skos:prefLabel"-->  v6
  v5 --"skos:prefLabel"-->  v7