195_submission_citation_database

citation
submission
database

Find proteins backed by a direct-submission citation, and which database (e.g. EMBL/GenBank/DDBJ, PDB) that submission was made to

Use at

https://sparql.uniprot.org/sparql/

PREFIX up: <http://purl.uniprot.org/core/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT DISTINCT
  ?protein
  ?citation
  ?title
  ?database
  ?date
WHERE {
  ?protein a up:Protein ;
    up:annotation ?annotation .
  ?linkToEvidence rdf:object ?annotation ;
    up:attribution ?attribution .
  ?attribution up:source ?citation .
  ?citation a up:Submission_Citation ;
    up:title ?title ;
    up:submittedTo ?database ;
    up:date ?date .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v2("?annotation")
  v4("?attribution")
  v5("?citation"):::projected 
  v7("?database"):::projected 
  v8("?date"):::projected 
  v3("?linkToEvidence")
  v1("?protein"):::projected 
  v6("?title"):::projected 
  c7(["up:Submission_Citation"]):::iri 
  c2(["up:Protein"]):::iri 
  v1 --"a"-->  c2
  v1 --"up:annotation"-->  v2
  v3 --"rdf:object"-->  v2
  v3 --"up:attribution"-->  v4
  v4 --"up:source"-->  v5
  v5 --"a"-->  c7
  v5 --"up:title"-->  v6
  v5 --"up:submittedTo"-->  v7
  v5 --"up:date"-->  v8