61

Select the Gene Protein Reaction sets for Human (Ensembl Gene, Human UniProtKB, Catalyzed Rhea reactions)

Use at

• https://sparql.uniprot.org/sparql/

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX taxon: <http://purl.uniprot.org/taxonomy/>
PREFIX up: <http://purl.uniprot.org/core/>

SELECT
?ensemblGene ?protein ?rhea
WHERE {
  ?protein up:reviewed true ;
           up:organism taxon:9606 .
  ?protein up:annotation ?caa ;
           rdfs:seeAlso ?ensemblTranscript .
  ?ensemblTranscript up:database <http://purl.uniprot.org/database/Ensembl> .
	?caa up:catalyticActivity ?ca .
  ?ca up:catalyzedReaction ?rhea .
  ?ensemblTranscript up:transcribedFrom ?ensemblGene 
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v4("?ca")
  v2("?caa")
  v6("?ensemblGene"):::projected 
  v3("?ensemblTranscript")
  v1("?protein"):::projected 
  v5("?rhea"):::projected 
  c8([http://purl.uniprot.org/database/Ensembl]):::iri 
  c2(["true^^xsd:boolean"]):::literal 
  c4(["taxon:9606"]):::iri 
  v1 --"up:reviewed"-->  c2
  v1 --"up:organism"-->  c4
  v1 --"up:annotation"-->  v2
  v1 --"rdfs:seeAlso"-->  v3
  v3 --"up:database"-->  c8
  v2 --"up:catalyticActivity"-->  v4
  v4 --"up:catalyzedReaction"-->  v5
  v3 --"up:transcribedFrom"-->  v6