63_diseases_involving_enzymes_located_in_mitochondrion

Find (Human genetic) diseases that are thought to be related to Enzymes, known to be located in the Mitochondrion

Use at

• https://sparql.uniprot.org/sparql/

PREFIX taxon: <http://purl.uniprot.org/taxonomy/>
PREFIX up: <http://purl.uniprot.org/core/>

SELECT
  DISTINCT
    ?disease
WHERE {
  ?protein a up:Protein ;
  up:organism taxon:9606 ;
  up:annotation ?disease_annotation ,
                ?subcellularLocation .
  {
    ?protein up:enzyme [] .
  } UNION {
    ?protein up:annotation/a up:Catalytic_Activity_Annotation .
  }
  ?disease_annotation a up:Disease_Annotation ;
    up:disease ?disease .
  ?subcellularLocation a up:Subcellular_Location_Annotation ;
    up:locatedIn ?location .
  ?location up:cellularComponent ?component .
  ?component up:partOf* <http://purl.uniprot.org/locations/173> .
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v6("?component")
  v4("?disease"):::projected 
  v2("?disease_annotation")
  v5("?location")
  v1("?protein")
  v3("?subcellularLocation")
  a1((" "))
  a2((" "))
  c14([http://purl.uniprot.org/locations/173]):::iri 
  c8(["up:Disease_Annotation"]):::iri 
  c4(["taxon:9606"]):::iri 
  c10(["up:Subcellular_Location_Annotation"]):::iri 
  c7(["up:Catalytic_Activity_Annotation"]):::iri 
  c2(["up:Protein"]):::iri 
  v1 --"a"-->  c2
  v1 --"up:organism"-->  c4
  v1 --"up:annotation"-->  v2
  v1 --"up:annotation"-->  v3
  subgraph union0[" Union "]
  subgraph union0l[" "]
    style union0l fill:#abf,stroke-dasharray: 3 3;
    v1 --"up:annotation"-->  a2
    a2 --"a"-->  c7
  end
  subgraph union0r[" "]
    style union0r fill:#abf,stroke-dasharray: 3 3;
    v1 --"up:enzyme"-->  a1
  end
  union0r <== or ==> union0l
  end
  v2 --"a"-->  c8
  v2 --"up:disease"-->  v4
  v3 --"a"-->  c10
  v3 --"up:locatedIn"-->  v5
  v5 --"up:cellularComponent"-->  v6
  v6 --"up:partOf"-->  c14