76_enzymes_with_mutagenesis_affecting_active_site

rq turtle/ttl

• active site
• enzyme
• mutagenesis
• search within sequence
• list

Find enzymes, where the active site is a region affected by mutagenesis and show the comment regarding mutagenesis effect.

Use at

• https://sparql.uniprot.org/sparql/

PREFIX faldo: <http://biohackathon.org/resource/faldo#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX up: <http://purl.uniprot.org/core/>

SELECT
  ?protein ?mutagenesisBeginPosition ?activeSiteBeginPosition ?mutagenesisRangeEndPosition ?mutagenesisComment
WHERE {
  ?protein up:annotation ?activeSiteAnnotation ,
      ?mutagenesisAnnotation .
  ?mutagenesisAnnotation a up:Mutagenesis_Annotation ;
     up:range ?mutagenesisRange ;
	 rdfs:comment ?mutagenesisComment .
  ?activeSiteAnnotation a up:Active_Site_Annotation ;
    up:range ?activeSiteRange .
  ?activeSiteRange faldo:begin ?activeSiteBegin .
  ?activeSiteBegin faldo:position ?activeSiteBeginPosition ;
    faldo:reference ?sequence .
  ?mutagenesisRange faldo:begin ?mutagenesisRangeBegin ;
    faldo:end ?mutagenesisRangeEnd .
  ?mutagenesisRangeBegin faldo:position ?mutagenesisBeginPosition ;
    faldo:reference ?sequence .
  ?mutagenesisRangeEnd faldo:position ?mutagenesisRangeEndPosition .
  FILTER(?mutagenesisBeginPosition <= ?activeSiteBeginPosition && ?activeSiteBeginPosition <= ?mutagenesisRangeEndPosition)
}

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v5("?activeSiteAnnotation")
  v10("?activeSiteBegin")
  v2("?activeSiteBeginPosition"):::projected 
  v9("?activeSiteRange")
  v6("?mutagenesisAnnotation")
  v1("?mutagenesisBeginPosition"):::projected 
  v8("?mutagenesisComment"):::projected 
  v7("?mutagenesisRange")
  v12("?mutagenesisRangeBegin")
  v13("?mutagenesisRangeEnd")
  v3("?mutagenesisRangeEndPosition"):::projected 
  v4("?protein"):::projected 
  v11("?sequence")
  c6(["up:Active_Site_Annotation"]):::iri 
  c3(["up:Mutagenesis_Annotation"]):::iri 
  f0[["?mutagenesisBeginPosition <= ?activeSiteBeginPosition?activeSiteBeginPosition <= ?mutagenesisRangeEndPosition"]]
  f0 --> v1
  f0 --> v2
  f0 --> v3
  v4 --"up:annotation"-->  v5
  v4 --"up:annotation"-->  v6
  v6 --"a"-->  c3
  v6 --"up:range"-->  v7
  v6 --"rdfs:comment"-->  v8
  v5 --"a"-->  c6
  v5 --"up:range"-->  v9
  v9 --"faldo:begin"-->  v10
  v10 --"faldo:position"-->  v2
  v10 --"faldo:reference"-->  v11
  v7 --"faldo:begin"-->  v12
  v7 --"faldo:end"-->  v13
  v12 --"faldo:position"-->  v1
  v12 --"faldo:reference"-->  v11
  v13 --"faldo:position"-->  v3