neXtProt/NXQ_00259

Proteins involved in diseases with clinical manifestations that include long organs

Use at

• https://sparql.nextprot.org/sparql

PREFIX : <http://nextprot.org/rdf/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX ncit: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sio: <http://semanticscience.org/resource/>

SELECT DISTINCT ?entry (str(?gen) as ?genx) ?umlsTerm WHERE {
 SERVICE <https://rdf.disgenet.org/sparql> {
 SELECT DISTINCT ?protein ?umlsTerm WHERE {
 ?gda sio:SIO_000628 ?gene,?disease .
 ?disease a sio:SIO_010056 . # traits or phenotypes
 ?disease dcterms:title ?umlsTerm .
 filter(contains(str(?umlsTerm),"Long "))
 ?gene a ncit:C16612; sio:SIO_010078 ?protein .
 }
 }
 BIND(IRI(replace(str(?protein),"purl","www")) AS ?unipage) .
 ?entry :swissprotPage ?unipage .
 ?entry :gene / :recommendedName / rdfs:label ?gen .
} order by ?entry

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v5("?disease")
  v1("?entry"):::projected 
  v3("?gda")
  v8("?gen"):::projected 
  v4("?gene")
  v9("?genx")
  v6("?protein")
  v2("?umlsTerm"):::projected 
  v7("?unipage")
  a1((" "))
  a2((" "))
  c5(["sio:SIO_010056"]):::iri 
  c7(["ncit:C16612"]):::iri 
  subgraph s1["https://rdf.disgenet.org/sparql"]
    style s1 stroke-width:4px;
    f0[["contains(str(?umlsTerm),'Long ')"]]
    f0 --> v2
    v3 --"sio:SIO_000628"-->  v4
    v3 --"sio:SIO_000628"-->  v5
    v5 --"a"-->  c5
    v5 --"dcterms:title"-->  v2
    v4 --"a"-->  c7
    v4 --"sio:SIO_010078"-->  v6
  end
  bind1[/"replace(str(?protein),'purl','www')"/]
  v6 --o bind1
  bind1 --as--o v7
  v1 --":swissprotPage"-->  v7
  v1 --":gene"-->  a1
  a1 --":recommendedName"-->  a2
  a2 --"rdfs:label"-->  v8
  bind2[/"str(?gen)"/]
  v8 --o bind2
  bind2 --as--o v9